Timers

Step 1

Introduction to timers

It might not seem like a big deal, but keeping track of time in programming is an incredibly useful and powerful skill to have! Your Smart Inventor Board has a built-in timer that can help you time how long a button is held down for and create repetitive, time-dependent events. In this lesson, you’re going to learn how to program that timer to help you fly your CoDrone.

One thing to remember: the Smart Inventor Board’s timer only works when the board is powered on!

Step 2

millis() and micros()

Arduino has two timer functions: millis(), which measures milliseconds, and micros(), which measures microseconds. There are 1,000 milliseconds in 1 second and 1,000,000 microseconds in 1 second.

Both functions work exactly the same way — like stopwatches. As soon as the Smart Inventor Board is on, they start measuring the number of milliseconds or microseconds that pass by. Even if you don’t use a timer function in your program, the timer is still going on in the background!

The millis() function is the more commonly used timer, so you’re going to be using that in your CoDrone programs. Just so you can see how quickly milliseconds pass by, upload this code into a new sketch in Arduino, connect your remote, and open up the serial monitor.

void setup() {
  Serial.begin(9600);
}

void loop() {
  Serial.println(millis());
}

Step 3

Timer variable

One thing that’s really important to remember is that millis() only tells you the time from when the Smart Inventor Board was started or reset. The timer cannot be paused, reset, or accept any inputs. All you can do is save its current value, which we know sounds boring but we promise this will help you do better stuff! To save this value, you need to create a variable that looks something like this:

unsigned long CurrentTime = millis()

What all of that means:

A long is a variable with a very large storage capacity. It can store numbers from -2,147,483,648 to 2,147,483,647. You’re using this type of variable because you are going to be dealing with a lot of milliseconds. For example, if you turned your Smart Inventor Board on and left it for a minute, you would already have 60,000 milliseconds!
Adding unsigned in front of it just means you’re not going to use any negative numbers. If you do this, you can use more positive numbers. The range for an unsigned long is 0 to 4,294,967,295.
CurrentTime is the variable name. You can name your variable whatever you like, as long as it makes sense and you remember it!

Step 4

Timer problem

Like we said, the one problem with the millis() function: it only tells you the time from when the program was started, which is usually when the Smart Inventor Board was turned on. That means that if you have a code like the one below, which has your CoDrone taking off at 1000 milliseconds, you will never see your drone take off because it takes more than 1000 milliseconds to establish communication and connect!

void loop() {
  if (millis() < 1000) {
    CoDrone.setThrottle(70);
  }
  else {
    CoDrone.emergencyStop();
  }
}

Step 5

StartTime

To work around this timer issue, you can use a global variable called StartTime, another global variable called StartFlag, subtraction, and flags! To set up your code, include the CoDrone library and make sure StartTime is an unsigned long variable. Next, in void setup, establish communication, connect to a nearby drone, and have it take off for 2 seconds.

#include <CoDrone.h>

unsigned long StartTime;
int StartFlag;
 
void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();

  CoDrone.takeoff();   
}

Quick explanation about how StartTimewill work with this code: you’ll be using StartTime = millis()with a flag so the timer only starts when the flag is on. Next, you’ll include lines so that the start time will be subtracted from the current milliseconds to give you a true idea of how much time has passed. Check the images below for another explanation!

Step 6

Flag setup

Like we said in the last step, the timer will turn on when StartFlag is triggered. That will happen when sensor 11 is covered. To set that up, include the following block of code in void loop:

void loop() {
  byte bt1 = digitalRead(11);
  byte bt4 = digitalRead(14);
  byte bt8 = digitalRead(18);

  if (bt1) {
    StartTime = millis();
    StartFlag = 1;
  }

This is the pseudocode:

Sensors 11, 14, and 18 are inputs.
If sensor 11 is covered, save the beginning point of the timer to milliseconds and trigger the start flag.

Step 7

Flag events

Once you set up the if statement for when the flag is triggered, you can add events! To do this, you just need to use if, else if, and else statements. However, you will also need to include the times using the current timer value minus the start time’s value.

if (StartFlag == 1) {
    if (millis() - StartTime < 2000) {
      CoDrone.setThrottle(30);
      CoDrone.move();
    }
    else if (millis() - StartTime < 5000) {
      CoDrone.setPitch(70);
      CoDrone.setThrottle(0);
      CoDrone.move();
    }
    else if (millis() - StartTime < 7000){
      CoDrone.setRoll(40);
      CoDrone.setPitch(0);
      CoDrone.move();
    }
}

This is the pseudocode:

If StartFlag is triggered:

If the current milliseconds minus the start time is less than 2000 milliseconds, throttle up at 30.
Else, if the current milliseconds minus the start time is less than 5000 milliseconds, pitch forward at 70.
Else, if the current milliseconds minus the start time is less than 7000 milliseconds, roll right at 40.

The best part about this code: each statement takes all of the previous time into account, so the first line won’t always be repeating!

Step 8

Landing flag

You can always add more else if statements if you want to add more flight events, but when you’re ready for your CoDrone to land, you can just turn StartFlag off!

else { 
  CoDrone.land();
  StartFlag = 0;
}

Step 9

Kill switch

Just because you’re using timers and flags does not mean you get to drop the kill switch from your program! Include this after the landing statement:

if (bt8) {
  CoDrone.emergencyStop();
  StartFlag = 0;
}

Since timers don’t stop your code from looping, sensor 18 will be constantly checked so you can use it at any point in your program. Make sure you also set StartFlagto 0 so your CoDrone doesn’t receive any more commands after it lands.

Step 10

Final code

Your final code should look like this:

#include <CoDrone.h>

unsigned long StartTime;
int StartFlag;
 
void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();

  CoDrone.takeoff();   //take off and hover for 3 seconds 
  CoDrone.move(3);
}

void loop() {
  byte bt1 = digitalRead(11);
  byte bt4 = digitalRead(14);
  byte bt8 = digitalRead(18);
    
  //button trigger timer
  if (bt1) {
    StartTime = millis();
    StartFlag = 1;
  }

 //as time increases, the CoDrone will go up-> forward-> right-> landing
 if (StartFlag == 1) {
    if (millis() - StartTime < 2000) {
      CoDrone.setThrottle(30);
      CoDrone.move();
    }
    else if (millis() - StartTime < 5000) {
      CoDrone.setPitch(70);
      CoDrone.setThrottle(0);
      CoDrone.move();
    }
    else if (millis() - StartTime < 7000){
      CoDrone.setRoll(40);
      CoDrone.setPitch(0);
      CoDrone.move();
    }
    else {
      CoDrone.land();
      StartFlag = 0;
    }
  }
  
  if (bt8) {
     CoDrone.emergencyStop();
     StartFlag = 0;
  }
}

Step 11

Challenge

Challenge: Square Dancing

Write a program that flies your CoDrone in a square!

Rules:

You have to include a kill switch!
You must use timers and flags.

This lesson works with:

Grade level:

Approx. time required:

CSTA

CCSS