Program the Turret Bot

The Turret Bot is controlled with the Smart Inventor Board’s IR sensors. The right and left sensors will move the Turret Bot in those directions and the center IR sensor is used for firing the rubber band.

This is the turret bot’s pseudocode:

• Check the left, center, and right sensors.
• If the right sensor senses an object, swing to the right.
• Else, if the left sensor senses an object, swing to the left.
• Else, if the center sensor senses an object, shoot the rubber band.

The first thing you need to do in your code is set up the Smart Inventor library. Since your motors will be controlling the turret, you need to include those in void setup().

#include <SmartInventor.h>
 
void setup() {
  SmartInventor.DCMotorUse();
}

Your IR sensors are super important for this robot! The first thing you need to do is check the base levels that each sensor is reading. This will help you tell if the sensors are detecting something nearby.

In void setup(), you’ll be reading the sensors’ values, which you’re going to save in some variables. Not even IR sensors are perfect, so subtract 50 from each of the sensors to create a buffer.

You may or may not have realized this: your Smart Inventor Board is upside down! For the Turret Bot, the right sensor is pin 19 and the left sensor is pin 21.

#include <SmartInventor.h>

int baseLevelLeft;
int baseLevelCenter;
int baseLevelRight;

 
void setup() {
  SmartInventor.DCMotorUse();
 
  baseLevelLeft = analogRead(21) - 50;
  baseLevelCenter = analogRead(20) - 50;
  baseLevelRight = analogRead(19) - 50;
}

In void loop(), include code that will read the sensors and check if they detect anything nearby. The good thing about using if, else if, and else statements for this part of the code is that each sensor will be checked one at a time, which will prevent your Turret Bot from just wiggling back and forth!

void loop() {
  // check sensors
  int leftSensor = analogRead(21);
  int centerSensor = analogRead(20);
  int rightSensor = analogRead(19);
 
  //if right, turn right
  if(rightSensor < baseLevelRight)
  {
 
  }
  // if left, turn left
  else if(leftSensor < baseLevelLeft)
  {
 
  }
  // if center, shoot
  else if(centerSensor < baseLevelCenter)
  {
 
  }
}

Next, add your motors to void loop(). Your motors are going to move in small increments, so they’ll turn and stop for small amounts of time. This means you’ll have better control of your motors, which also means better control of shooting rubber bands!

void loop() {
  // check sensors
  int leftSensor = analogRead(21);
  int centerSensor = analogRead(20);
  int rightSensor = analogRead(19);
 
  //if right, turn right
  if(rightSensor < baseLevelRight)
  {
    //move right
    SmartInventor.DCMotor(M1, CW, 100);
    delay(6);
    SmartInventor.DCMotor(M1, STOP, 0);
    delay(2);
  }
  // if left, turn left
  else if(leftSensor < baseLevelLeft)
  {    
    // move left
    SmartInventor.DCMotor(M1, CCW, 100);
    delay(6);
    SmartInventor.DCMotor(M1, STOP, 0);
    delay(2);
  }
  // if center, shoot
  else if(centerSensor < baseLevelCenter)
  {
    // shoot
    SmartInventor.DCMotor(M2, CW, 100);
    delay(300);
    SmartInventor.DCMotor(M2, STOP, 0);
    delay(100);
  }
 
}

You can also program your LEDs so they can give you extra feedback on what exactly your Turret Bot is doing. The two left LEDs will be on when the left sensor is covered, the two right LEDs will be on when the right sensor is covered, and the two middle LEDs will be on when the middle sensor is covered.

The first thing you need to do is set up the LEDs as outputs. You can do this in void setup() with pinMode(). In void loop(), use digitalWrite() with pairs of LEDs so they turn on and off with certain sensors. These will be within the if, else if, and else statements that you already wrote.

#include <SmartInventor.h>
 
int baseLevelLeft;
int baseLevelCenter;
int baseLevelRight;
 
void setup() {
  SmartInventor.DCMotorUse();
 
  baseLevelLeft = analogRead(21) - 50;
  baseLevelCenter = analogRead(20) - 50;
  baseLevelRight = analogRead(19) - 50;
 
  pinMode(11, OUTPUT);
  pinMode(12, OUTPUT);
  pinMode(14, OUTPUT);
  pinMode(15, OUTPUT);
  pinMode(17, OUTPUT);
  pinMode(18, OUTPUT);
}
 
void loop() {
  // check sensors
  int leftSensor = analogRead(21);
  int centerSensor = analogRead(20);
  int rightSensor = analogRead(19);
 
  //if right, turn right
  if(rightSensor < baseLevelRight)
  {
    // Right LEDs on
    digitalWrite(11, HIGH);
    digitalWrite(12, HIGH);
 
    //move right
    SmartInventor.DCMotor(M1, CW, 100);
    delay(6);
    SmartInventor.DCMotor(M1, STOP, 0);
    delay(2);
 
    // Right LEDs off
    digitalWrite(11, LOW);
    digitalWrite(12, LOW);
  }
  // if left, turn left
  else if(leftSensor < baseLevelLeft)
  {
    // left LEDs on
    digitalWrite(17, HIGH);
    digitalWrite(18, HIGH);
 
    // move left
    SmartInventor.DCMotor(M1, CCW, 100);
    delay(6);
    SmartInventor.DCMotor(M1, STOP, 0);
    delay(2);
 
    // left LEDs off
    digitalWrite(17, LOW);
    digitalWrite(18, LOW);
  }
  // if center, shoot
  else if(centerSensor < baseLevelCenter)
  {
    // center LEDs on
    digitalWrite(14, HIGH);
    digitalWrite(15, HIGH);
 
    // shoot
    SmartInventor.DCMotor(M2, CW, 100);
    delay(300);
    SmartInventor.DCMotor(M2, STOP, 0);
    delay(100);
 
    // center LEDs off
    digitalWrite(14, LOW);
    digitalWrite(15, LOW);
  }
 
}

Your final code should look something like the one below.

#include <SmartInventor.h> 

int baseLevelLeft;
int baseLevelCenter;
int baseLevelRight; 

void setup() {  
    SmartInventor.DCMotorUse();  
 
    baseLevelLeft = analogRead(21) - 50;  
    baseLevelCenter = analogRead(20) - 50;  
    baseLevelRight = analogRead(19) - 50;   

    pinMode(11, OUTPUT);  
    pinMode(12, OUTPUT);  
    pinMode(14, OUTPUT);  
    pinMode(15, OUTPUT);  
    pinMode(17, OUTPUT);  
    pinMode(18, OUTPUT);
} 

void loop() {  
    // check sensors  
    int leftSensor = analogRead(21);  
    int centerSensor = analogRead(20);  
    int rightSensor = analogRead(19);   

    //if right, turn right  
    if(rightSensor < baseLevelRight)  
    {    
        // Right LEDs on    
        digitalWrite(11, HIGH);    
        digitalWrite(12, HIGH);     

        //move right    
        SmartInventor.DCMotor(M1, CW, 100);    
        delay(6);    
        SmartInventor.DCMotor(M1, STOP, 0);    
        delay(2);     

        // Right LEDs off    
        digitalWrite(11, LOW);    
        digitalWrite(12, LOW);  
    }  

    // if left, turn left  
    else if(leftSensor < baseLevelLeft)  
    {    
        // left LEDs on    
        digitalWrite(17, HIGH);    
        digitalWrite(18, HIGH);     

        // move left    
        SmartInventor.DCMotor(M1, CCW, 100);    
        delay(6);    
        SmartInventor.DCMotor(M1, STOP, 0);    
        delay(2);     

        // left LEDs off    
        digitalWrite(17, LOW);    
        digitalWrite(18, LOW);  
    }  

    // if center, shoot  
    else if(centerSensor < baseLevelCenter)  
    {    
        // center LEDs on    
        digitalWrite(14, HIGH);    
        digitalWrite(15, HIGH);     

        // shoot    
        SmartInventor.DCMotor(M2, CW, 100);    
        delay(300);    
        SmartInventor.DCMotor(M2, STOP, 0);    
        delay(100);     

        // center LEDs off    
        digitalWrite(14, LOW);    
        digitalWrite(15, LOW);  
    } 
}

Still not sure about this lesson or want to check your program? Watch the video!