Controller LEDs

The CoDrone controller has 8 built-in blue LEDs that can be programmed. If you look at the Rokit Smart Inventor Board map, these LEDs each share pins 11 through 18 with the bottom digital IR sensors, but you can switch between using the pins as sensors or as LEDs. To do this, you need to use different pin modes.

The digital IR sensors should be written as inputs, which means they read information. With CoDrone Pro, this usually looks like you covering a sensor with your finger so it’s triggered. Using the IR sensors as inputs looks like this:

pinMode(11,INPUT)

pinMode(11,OUTPUT)

If you want to turn your LEDs on (or off!), you need to use the digitalWrite() function. This is what it will look like in your code:

digitalWrite(pin number, output)

void setup() {
  pinMode(11, OUTPUT);
}

void loop() {
  digitalWrite(11, HIGH);
  delay(2000);
  digitalWrite(11, LOW);
  delay(2000);
}

One of the ways you can program your remote control’s LEDs is with flags! In this program, they’re named Mode instead, but again, you can name your flag variable whatever you want. LEDs 13 and 16 are programmed as outputs and sensor 18 is programmed as an input, so when sensor 18 is triggered, LEDs 13 and 16 will do something. You can repeatedly cover sensor 18 to see all of the different combinations!

Warning: you need to connect to a CoDrone for this program in order for it to work, but it will not take off or fly.

#include <CoDrone.h>

int Mode;

void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();

  digitalWrite(13, LOW);
  digitalWrite(16, LOW);
}

void loop() {
  byte bt8 = digitalRead(18);

  if (bt8) {
    Mode = Mode + 1;

    if (Mode > 3) {
      Mode = 0;
    }

    if ( Mode == 0) {
      digitalWrite(13, LOW);
      digitalWrite(16, LOW);
    }
    else if ( Mode == 1) {
      digitalWrite(13, HIGH);
      digitalWrite(16, LOW);
    }
    else if ( Mode == 2) {
      digitalWrite(13, LOW);
      digitalWrite(16, HIGH);
    }
    else if ( Mode == 3) {
      digitalWrite(13, HIGH);
      digitalWrite(16, HIGH);
    }

    CoDrone.Buzz(3000 + (Mode * 2000), 7);
    delay(400); 
  }
}

There might be times when you can’t decide whether to use a pin as an LED or IR sensor. You can use one pin as both an input and output in the same program. All you need to do is switch to input right before your sensor read and switch back to output right after. It should look something like this, and you’ll need to set it up at the beginning of void loop:

pinMode(18, INPUT); 
byte bt8 = digitalRead(18); 
pinMode(18, OUTPUT);

#include <CoDrone.h>

int Flag;

void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();
}

void loop() {
  pinMode(18, INPUT);
  byte bt8 = digitalRead(18);
  pinMode(18, OUTPUT);

  if (bt8) {
    if (Flag == 0) {
      Flag = 1; 
    } 
    else {
      Flag = 0;
    } 

    CoDrone.Buzz(4000 + (Flag * 2000), 7);
    delay(400);
  }

  if (Flag == 1) {
    digitalWrite(18, HIGH);
  }
  else if (Flag == 0) {
    digitalWrite(18, LOW);
  }
}

An LED’s brightness, or intensity, can be changed by quickly turning the LED on and off. The Smart Inventor Board switches the LED on and off faster than your eyes can notice, so all you’ll see is a decrease in brightness. For example, if you wanted your LED to be at full brightness, you could just leave it on the entire time. However, if you wanted your LED to be on at less than half of the brightness, you would need to leave it on less than half of the time. To do this, you would need to use Pulse Width Modulation (PWM).

Really quick side note: in this case, a pulse is a quick switch from off to on and then back to off again. If you did this with your LED, it would flick on and off once, and it would happen so fast that you probably wouldn’t see it.

If you want to decrease the brightness of your LEDs to less than half, you’ll need more off time in between each of the pulses. Make sure there isn’t too much off time since your eyes will actually notice that the LEDs are off instead of just appearing dim. Check the image below to see what that looks like!

Not sure how much time to leave in between each pulse? The start of one pulse to the start of another is about 20 milliseconds. If you wanted your LEDs to be on for less than half of the brightness, you would set the LEDs to be on for less than 10 milliseconds. Check the image to see what very low intensity looks like, since you’ll be using that for your example code!

Try the code below for dim LEDs!

#include <CoDrone.h>

unsigned long SetTime;

void setup() {
}

void loop() {
  if (micros() - SetTime < 100) {
    digitalWrite(13, HIGH);
  }
  else if (micros() - SetTime < 20000) {
    digitalWrite(13, LOW);
  }
  else {
    SetTime = micros();
  }
}

Pulse width is the amount of time that the pulse is on. For example, if you have a 10 millisecond pulse, your pulse width is also 10 milliseconds. You can set your pulse width to a variable like the one below so you can do more with it!

if (micros() - SetTime < PulseWidth)

#include <CoDrone.h>

unsigned long SetTime;
unsigned long PulseWidth;

void setup() {
}

void loop() {
  int LeftJoystick = CoDrone.AnalogScaleChange(analogRead(23)); 
  PulseWidth = (LeftJoystick + 100)*50;

  if (micros() - SetTime < PulseWidth) {
    digitalWrite(13, HIGH); 
  }
  else if (micros() - SetTime < 20000) {
    digitalWrite(13, LOW);
  } 
  else {
    SetTime = micros(); 
  } 
}